Clone Scan

mIRC sorun, ders, addon ve script paylaşım bölümü..
Post Reply
User avatar
Immortal
Admin
Admin
Posts: 337
Joined: 01 Sep 2009, 06:05

Clone Scan

Post by Immortal » 14 May 2010, 20:48

Code: Select all

alias scan {
  if (!%scan::clone) {
    if ($1) {
      if ($me ison $1) {
        echo -a ~ Starting scan on channel $+(",$1,".)
        set %scan::clone 1
        who $1
      }
      else echo -a ~ You must be on $+(",$1,") to perform a clone scan on it.
    }
    elseif ($left($active,1) == $chr(35)) {
      echo -a ~ Starting scan on channel $+(",$active,".)
      set %scan::clone 1
      who $active
    }
    else echo -a ~ If you don't supply a channel, your active window must be a one. ~
  }
  else echo -a ~ There is already a clone scan going on. ~
}
raw 352:*:{
  if (%scan::clone) {
    inc %scan::host:: [ $+ [ $4 ] ]
    set %scan::nick:: [ $+ [ $4 ] ] $iif(%scan::nick:: [ $+ [ $4 ] ],%scan::nick:: [ $+ [ $4 ] ] $+ $chr(44) $+($6),$+($6))
    haltdef
  }
}
raw 315:*:{
  if (%scan::clone) {
    var %scan::loop 1
    while (%scan::loop <= $var(%scan::host::*,0)) {
      if ($var(%scan::host::*,%scan::loop).value > 1) {
        echo -a ~ $+($var(%scan::host::*,%scan::loop).value) clones found on host $+(",$gettok($var(%scan::host::*,%scan::loop),3,58),") ( $+ $var(%scan::nick::*,%scan::loop).value $+ )
        inc %scan::loop
        set %scan::found 1
      }
      else inc %scan::loop
    }
    if (!%scan::found) echo -a ~ No clones found ~
    echo -a  ~ Clone scan complete. ~
    unset %scan::*
    haltdef
  }
} 
menu channel {
  -
  ~ Clone Scan ~: /scan
  -
}
Oda içindeki sağ tık menüsünden ulaşabilirsiniz.
AlwayS.BelievE.In.YouR.HearT.No.MatteR.WhaT

User avatar
Has}{araT
#Turkey Op
#Turkey Op
Posts: 88
Joined: 24 Mar 2010, 00:08

Ynt: Clone Dedector...

Post by Has}{araT » 14 May 2010, 21:20

Code: Select all

on *:JOIN:*: {
  var %ii $ialchan($wildsite,$chan,0)
  if (%ii > 1) {
    var %i 1
    while (%i <= %ii) {
      tokenize 32 $1- $ialchan($wildsite,$chan,%i).nick
      inc %i
    }
    echo -a 12 $+ $timestamp 9,1..............Clones7,1 detected in9,1 $chan $+ :12 $1- (4 $+ $wildsite $+ 12)............
  }
}
Last edited by Immortal on 14 May 2010, 21:23, edited 1 time in total.

User avatar
son
Posts: 66
Joined: 21 Apr 2010, 03:13

Ynt: Clone Scan

Post by son » 18 May 2010, 21:13

Avatarin nekadar sirin. sende sirinmisin okadar :)

Post Reply

Who is online

Users browsing this forum: No registered users and 1 guest